#AutoIt3Wrapper_UseX64=n                          ; 32Bit-Modus!

#Region ;************ Includes ************

#include-once

#include <GDIPlus.au3>

#include <Memory.au3>

#EndRegion ;************ Includes ************



#Region ASM-Code

#cs _CountUniqueColors                            ;

	Use32                                         ; 32Bit Modus!

	mov esi,dword[esp+4]                          ; Pixelstruct-Pointer holen

	mov ecx,dword[esp+8]                          ; Anzahl der Pixel holen (Pixelcounter)

	mov edi,dword[esp+12]                         ; Colorstruct-Pointer holen

	xor eax,eax                                   ; eax als Farbzaehler (auf null setzen)

	@pixel_count:                                 ; Anfang der Schleife fuer alle Pixel

	mov ebx,[esi]                                 ; Farbwert aus Pixelstruct holen

	and ebx,0xffffff                              ; Alphachannel eliminieren

	cmp byte[edi+ebx],0                           ; Wert aus der Colorstruct = 0?

	jnz @next                                     ; wenn nicht 0, dann wurde die Farbe bereits gezaehlt, weiter -> @next

	inc eax                                       ; den Farbzaehler um eins erhoehen

	mov byte[edi+ebx],1                           ; den Wert in der Colorstruct auf 1 setzen

	@next:

	add esi,4                                     ; den Pixelstruct-Pointer um 4 erhoehen (naechstes DWORD)

	dec ecx                                       ; Pixelcounter um eins verringern

	jnz @pixel_count                              ; wenn Pixelcount nocht nicht 0, dann Schleife wiederholen

	ret                                           ; eax (Farbzaehler) wird zurueckgegeben

#ce

#EndRegion ASM-Code



; $__IGUC_g_bCode entspricht dem obigen ASM-Code im Binaerformat

Global Const $__IGUC_g_bCode = '0x8B7424048B4C24088B7C240C31C08B1E81E3FFFFFF00803C1F00750540C6041F0183C6044975E7C3'

; Die Speichergroesse fuer den ASM-Code berechnen

Global Const $__IGUC_g_iMemSize = StringLen($__IGUC_g_bCode) / 2 - 1

; Achtung! Hier unbedingt virtuellen Speicher mit "_MemVirtualAlloc" anfordern, weil sonst

; (bei eingeschalteter Datenausfuehrungsverhinderung = DEP) AutoIt mit einer Fehlermeldung beendet wird.

Global Const $__IGUC_g_pMem = _MemVirtualAlloc(0, $__IGUC_g_iMemSize, $MEM_COMMIT, $PAGE_EXECUTE_READWRITE)

If $__IGUC_g_pMem = 0 Then Exit MsgBox(16, 'Error!', "Can't allocate virtual memory!")

; Struktur fuer den ASM-Code im virtuellen Speicher erstellen

Global $__IGUC_g_tCodeBuffer = DllStructCreate('byte[' & $__IGUC_g_iMemSize & ']', $__IGUC_g_pMem)

; den ASM-Code in den Speicher schreiben (wird unten bei DllCallAddress aufgerufen)

DllStructSetData($__IGUC_g_tCodeBuffer, 1, $__IGUC_g_bCode)



OnAutoItExitRegister('__IGUC_Exit')

_GDIPlus_Startup()



Func __IGUC_Exit()

	_MemVirtualFree($__IGUC_g_pMem, $__IGUC_g_iMemSize, $MEM_DECOMMIT)

	$__IGUC_g_tCodeBuffer = 0

	_GDIPlus_Shutdown()

EndFunc   ;==>__IGUC_Exit



Func _GDIPlus_ImageGetUniqueColors(ByRef $hImage)

	Local $aDim, $tBitmapData, $tPixel, $pPixel, $tColors, $pColors, $aRet, $iError = 0

	$aDim =  _GDIPlus_ImageGetDimension($hImage)

	$tBitmapData = _GDIPlus_BitmapLockBits($hImage, 0, 0, $aDim[0], $aDim[1], $GDIP_ILMREAD, $GDIP_PXF32PARGB)

	If @error Then Return SetError(@error, 0, -1)

	$tPixel = DllStructCreate('dword[' & $tBitmapData.Width * $tBitmapData.Height & '];', $tBitmapData.Scan0) ; Pixelstruct (dword = 32 Bit pro Pixel)

	If @error Then Return SetError(10 + @error, 0, -1)

	$pPixel = DllStructGetPtr($tPixel)

	$tColors = DllStructCreate('byte[' & 0xffffff + 1 & '];') ; Colorstruct (1 Byte pro Farbwert)

	If @error Then Return SetError(20 + @error, 0, -1)

	$pColors = DllStructGetPtr($tColors)

	$aRet = DllCallAddress('uint:cdecl', DllStructGetPtr($__IGUC_g_tCodeBuffer), 'ptr', $pPixel, 'dword', $tBitmapData.Width * $tBitmapData.Height, 'ptr', $pColors)

	$iError = 30 + @error

	_GDIPlus_BitmapUnlockBits($hImage, $tBitmapData)

	$tColors = 0

	$tPixel = 0

	$tBitmapData = 0

	Return SetError($iError, 0, (IsArray($aRet) ? $aRet[0] : -1))

EndFunc   ;==>_GDIPlus_ImageGetUniqueColors

#include <GDIPlus.au3>



Global $sImagefile = @ScriptDir & '\test.jpg'

Global $sNewFile = @ScriptDir & '\test_new.jpg'



_GDIPlus_Startup()

Global $hImage = _GDIPlus_BitmapCreateFromFile($sImagefile)



; Bild als JPG speichern mit Uebername der EXIF-Daten, 90% Qualitaet, Breite und Hoehe jeweils 25% und keine Drehung

_GDIPlus_ImageSaveAsJPG($hImage, $sNewFile, True, 90, 0.25, 0.25, 0)



_GDIPlus_BitmapDispose($hImage)

_GDIPlus_Shutdown()



If FileExists($sNewFile) Then ShellExecute($sNewFile)

Exit



#cs

    $iRotate = Type of rotation and flip:

    0 - No rotation and no flipping (A 180-degree rotation, a horizontal flip and then a vertical flip)

    1 - A 90-degree rotation without flipping (A 270-degree rotation, a horizontal flip and then a vertical flip)

    2 - A 180-degree rotation without flipping (No rotation, a horizontal flip followed by a vertical flip)

    3 - A 270-degree rotation without flipping (A 90-degree rotation, a horizontal flip and then a vertical flip)

    4 - No rotation and a horizontal flip (A 180-degree rotation followed by a vertical flip)

    5 - A 90-degree rotation followed by a horizontal flip (A 270-degree rotation followed by a vertical flip)

    6 - A 180-degree rotation followed by a horizontal flip (No rotation and a vertical flip)

    7 - A 270-degree rotation followed by a horizontal flip (A 90-degree rotation followed by a vertical flip)

#ce

Func _GDIPlus_ImageSaveAsJPG($hImage, $sSaveFile, $bEXIF = True, $iQuality = 90, $fScaleW = 1.0, $fScaleH = 1.0, $iRotate = 0)

    Local $hScaledBitmap, $sCLSID, $tData, $tParams, $bRet, $iError = 0

    $hScaledBitmap = _GDIPlus_ImageScale($hImage, $fScaleW, $fScaleH) ; das Bild skalieren (neue Bitmap wird erstellt)

    If $iRotate Then _GDIPlus_ImageRotateFlip($hScaledBitmap, $iRotate) ; die neue Bitmap drehen bzw. spiegeln (wenn gewuenscht)

    If $bEXIF Then ; die EXIF-Daten in die neue Bitmap kopieren (wenn gewuenscht)

        _GDIPlus_ImageCopyPropertyItems($hImage, $hScaledBitmap)

        If @error Then Return SetError(@error, @extended, False)

    EndIf

    $sCLSID = _GDIPlus_EncodersGetCLSID('JPG')

    $tParams = _GDIPlus_ParamInit(1)

    $tData = DllStructCreate('int Quality') ; Struktur fuer die JPG-Qualitaet erstellen

    DllStructSetData($tData, 'Quality', $iQuality) ; JPG-Qualitaet entsprechend setzen (von 0 = schlechteste bis 100 = beste)

    _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, 'Quality'))

    $bRet = _GDIPlus_ImageSaveToFileEx($hScaledBitmap, $sSaveFile, $sCLSID, $tParams)

    If @error Then $iError = 4

    _GDIPlus_BitmapDispose($hScaledBitmap)

    $tData = 0

    Return SetError($iError, 0, $bRet)

EndFunc   ;==>_GDIPlus_ImageSaveAsJPG



Func _GDIPlus_ImageCopyPropertyItems(ByRef $hSourceImage, ByRef $hDestImage)

    Local Const $tagGDIPPROPERTYITEM = 'uint id;uint length;ushort type;ptr value;'

    Local $aRes, $iSize, $iCount, $tBuffer, $pBuffer, $tGDIPPROPERTYITEM

    $aRes = DllCall($__g_hGDIPDll, 'uint', 'GdipGetPropertySize', 'hwnd', $hSourceImage, 'uint*', 0, 'uint*', 0)

    If @error Then Return SetError(1, @extended, False)

    $iSize = $aRes[2] ; $aRes[2] = Total size in bytes

    $iCount = $aRes[3] ; $aRes[3] = Number of property items

    $tBuffer = DllStructCreate('byte[' & $iSize & ']')

    $pBuffer = DllStructGetPtr($tBuffer)

    $aRes = DllCall($__g_hGDIPDll, 'uint', 'GdipGetAllPropertyItems', 'hwnd', $hSourceImage, 'uint', $iSize, 'uint', $iCount, 'ptr', $pBuffer)

    If @error Then Return SetError(2, @extended, False)

    For $i = 0 To $iCount - 1

        $tGDIPPROPERTYITEM = DllStructCreate($tagGDIPPROPERTYITEM, $pBuffer)

        $aRes = DllCall($__g_hGDIPDll, 'uint', 'GdipSetPropertyItem', 'hwnd', $hDestImage, 'ptr', $pBuffer)

        If @error Then Return SetError(3, @extended, False)

        $pBuffer += DllStructGetSize($tGDIPPROPERTYITEM)

        $tGDIPPROPERTYITEM = 0

    Next

    $tBuffer = 0

    Return True

EndFunc   ;==>_GDIPlus_ImageCopyPropertyItems

#Region ;************ Includes ************

#include-once

#include <GDIPlus.au3>

#EndRegion ;************ Includes ************



Global $__g_iIFFE_DEBUG = True ; True = Debug-Ausgaben eingeschaltet



If $__g_hGDIPDll = 0 Then

    _GDIPlus_Startup()

    OnAutoItExitRegister('__IFFE_Exit')

EndIf

Global Const $__g_aGDIPDecoders = _GDIPlus_Decoders()

Global Const $__g_sIFFE_Version = '1.0.0.0'

Global Const $__g_sIFFE_Date = '2017-10-16 12:00:00'



Func __IFFE_Exit()

    _GDIPlus_Shutdown()

EndFunc   ;==>__IFFE_Exit



;===============================================================================

; Function Name:   _GDIPlus_ImageFixFileExtension($sFilename)

; Description:     Diese Funktion korrigiert die Dateiendung einer Bilddatei,

;                  wenn die Bilddatei eine falsche Endung aufweist.

;                  Existiert der neue Dateiname bereits, wird der neue Dateiname

;                  um einen Zaehler " (n)" erweitert.

;                  Wenn die bereits existierende Datei allerdings inhaltsgleich

;                  (gleiche CRC32-Checksumme) ist, mit der neuen Datei,

;                  dann wird die Datei mit der falschen Endung geloescht.

; Parameter(s):    $sFilename = Dateiname und -pfad der Bilddatei

; Requirement(s):  #include <GDIPlus.au3>

; Return Value(s): bei Erfolg = der neue Dateiname

;                     @extended = 0 - die Datei wurde umbenannt

;                     @extended = 1 - die Datei wurde nicht umbenannt

;                     @extended = 2 - die Datei war identisch mit einer

;                                     bereits existierenden Datei

;                  im Fehlerfall wird 0 zurueckgegeben und

;                     @error = 1 wenn FileMove fehlgeschlagen ist

;                     @error = 2 wenn PathYetAnotherMakeUniqueName fehlgeschlagen ist

;                     @error = Rueckgabe von _GDIPlus_ImageGetRawFormat, wenn

;                              Datei nicht vorhanden oder keine Bilddatei

; Author(s):       Oscar & Bitnugger (www.autoit.de)

;===============================================================================

Func _GDIPlus_ImageFixFileExtension($sFilename)

    Local $hImage, $aRet, $iFormat = -1, $iError, $aExt, $sNewFile, $aCrc32[2]

    $hImage = _GDIPlus_ImageLoadFromFile($sFilename)

    $aRet = _GDIPlus_ImageGetRawFormat($hImage)

    $iError = @error

    _GDIPlus_ImageDispose($hImage)

    If $iError Then Return SetError($iError, 0, 0)

    For $i = 1 To $__g_aGDIPDecoders[0][0]

        If $aRet[1] = $__g_aGDIPDecoders[$i][5] Then

            $iFormat = $i

            ExitLoop

        EndIf

    Next

    If $iFormat = -1 Then Return SetError(30, 0, 0)

    __IFFE_DebugPrint('> _GDIPlus_ImageFixFileExtension(): FileName   = ' & $sFilename & @CRLF)

    __IFFE_DebugPrint('> _GDIPlus_ImageFixFileExtension(): Format     = ' & $__g_aGDIPDecoders[$iFormat][5] & @CRLF)

    __IFFE_DebugPrint('> _GDIPlus_ImageFixFileExtension(): Extensions = ' & $__g_aGDIPDecoders[$iFormat][6] & @CRLF)

    $aExt = StringSplit(StringReplace(StringLower($__g_aGDIPDecoders[$iFormat][6]), '*', ''), ';', 2)

    For $sExt In $aExt

        If $sExt = StringRegExpReplace($sFilename, '(?:.+)(\..+)', '$1') Then Return SetError(0, 1, $sFilename)

    Next

    $sNewFile = StringRegExpReplace($sFilename, '(.+)\..+', '$1') & $aExt[0]

    If FileExists($sNewFile) Then

        $aCrc32[0] = __IFFE_ComputeCrc32($sFilename)

        If @error Then Return SetError(40, 0, 0)

        $aCrc32[1] = __IFFE_ComputeCrc32($sNewFile)

        If @error Then Return SetError(40, 0, 0)

        If $aCrc32[0] = $aCrc32[1] Then

            __IFFE_DebugPrint(StringFormat('! _GDIPlus_ImageFixFileExtension(): Diese Dateien sind identisch:\r' & _

                    '! --> Crc32 = 0x%s  %s\t - Falsche Dateierweiterung  (wird gelöscht)\r' & _

                    '+ --> Crc32 = 0x%s  %s\t - Richtige Dateierweiterung (wird behalten)\r', _

                    $aCrc32[0], $sFilename, $aCrc32[1], $sNewFile))

            FileDelete($sFilename)

            Return SetError(0, 2, $sNewFile)

        EndIf

    EndIf

    $aRet = DllCall('shell32.dll', 'int', 'PathYetAnotherMakeUniqueName', 'wstr', '', 'wstr', $sNewFile, 'ptr', 0, 'ptr', 0)

    If @error Or Not $aRet[0] Then Return SetError(2, 0, 0)

    $sNewFile = $aRet[1]

    Return FileMove($sFilename, $sNewFile, 1) ? SetError(0, 0, $sNewFile) : SetError(1, 0, 0)

EndFunc   ;==>_GDIPlus_ImageFixFileExtension



Func __IFFE_DebugPrint($sString)

    If $__g_iIFFE_DEBUG Then ConsoleWrite($sString)

EndFunc   ;==>__IFFE_DebugPrint



Func __IFFE_ComputeCrc32($sFilePath)

    Local $hFile, $bData, $iLen, $tData, $aRet

    $hFile = FileOpen($sFilePath, $FO_BINARY)

    If $hFile = -1 Then Return SetError(1, 0, 0)

    $bData = FileRead($hFile)

    FileClose($hFile)

    $iLen = BinaryLen($bData)

    If $iLen = 0 Then Return SetError(2, 0, 0)

    $tData = DllStructCreate('byte[' & $iLen & ']')

    DllStructSetData($tData, 1, $bData)

    $aRet = DllCall('ntdll.dll', 'dword', 'RtlComputeCrc32', 'dword', 0, 'struct*', DllStructGetPtr($tData), 'int', $iLen)

    If @error Or Not $aRet[0] Then Return SetError(@error + 10, @extended, 0)

    Return Hex($aRet[0], 8)

EndFunc   ;==>__IFFE_ComputeCrc32